mirror of
https://github.com/ghostty-org/ghostty.git
synced 2025-06-05 15:08:38 +03:00
5ad8ea6b22
Fixes #6727 The major change in this commit is to consolidate all the C imports in a single decl in main.zig. This is required for Zig 0.14. Without it, the problem in #6727 will happen. I was never able to minimize why this happens in order to open a Zig bug. Beyond this, I fixed the build.zig and build.zig.zon to work with Zig 0.14 so that we can test building `pkg/macos` in isolation. There are no downstream impacting changes in the build.zig files.
104 lines
2.9 KiB
Zig
104 lines
2.9 KiB
Zig
const std = @import("std");
|
|
const assert = std.debug.assert;
|
|
const Allocator = std.mem.Allocator;
|
|
const foundation = @import("../foundation.zig");
|
|
const text = @import("../text.zig");
|
|
const c = @import("c.zig").c;
|
|
|
|
pub const AttributedString = opaque {
|
|
pub fn create(
|
|
str: *foundation.String,
|
|
attributes: *foundation.Dictionary,
|
|
) Allocator.Error!*AttributedString {
|
|
return @constCast(@ptrCast(c.CFAttributedStringCreate(
|
|
null,
|
|
@ptrCast(str),
|
|
@ptrCast(attributes),
|
|
) orelse return Allocator.Error.OutOfMemory));
|
|
}
|
|
|
|
pub fn release(self: *AttributedString) void {
|
|
foundation.CFRelease(self);
|
|
}
|
|
|
|
pub fn getLength(self: *AttributedString) usize {
|
|
return @intCast(c.CFAttributedStringGetLength(@ptrCast(self)));
|
|
}
|
|
|
|
pub fn getString(self: *AttributedString) *foundation.String {
|
|
return @ptrFromInt(@intFromPtr(
|
|
c.CFAttributedStringGetString(@ptrCast(self)),
|
|
));
|
|
}
|
|
};
|
|
|
|
pub const MutableAttributedString = opaque {
|
|
pub fn create(cap: usize) Allocator.Error!*MutableAttributedString {
|
|
return @as(
|
|
?*MutableAttributedString,
|
|
@ptrFromInt(@intFromPtr(c.CFAttributedStringCreateMutable(
|
|
null,
|
|
@intCast(cap),
|
|
))),
|
|
) orelse Allocator.Error.OutOfMemory;
|
|
}
|
|
|
|
pub fn release(self: *MutableAttributedString) void {
|
|
foundation.CFRelease(self);
|
|
}
|
|
|
|
pub fn replaceString(
|
|
self: *MutableAttributedString,
|
|
range: foundation.Range,
|
|
replacement: *foundation.String,
|
|
) void {
|
|
c.CFAttributedStringReplaceString(
|
|
@ptrCast(self),
|
|
@bitCast(range),
|
|
@ptrCast(replacement),
|
|
);
|
|
}
|
|
|
|
pub fn setAttribute(
|
|
self: *MutableAttributedString,
|
|
range: foundation.Range,
|
|
key: anytype,
|
|
value: ?*anyopaque,
|
|
) void {
|
|
const T = @TypeOf(key);
|
|
const info = @typeInfo(T);
|
|
const Key = if (info != .pointer) T else info.pointer.child;
|
|
const key_arg = if (@hasDecl(Key, "key"))
|
|
key.key()
|
|
else
|
|
key;
|
|
|
|
c.CFAttributedStringSetAttribute(
|
|
@ptrCast(self),
|
|
@bitCast(range),
|
|
@ptrCast(key_arg),
|
|
value,
|
|
);
|
|
}
|
|
|
|
pub fn getLength(self: *MutableAttributedString) usize {
|
|
return @intCast(c.CFAttributedStringGetLength(@ptrCast(self)));
|
|
}
|
|
};
|
|
|
|
test "mutable attributed string" {
|
|
//const testing = std.testing;
|
|
|
|
const str = try MutableAttributedString.create(0);
|
|
defer str.release();
|
|
|
|
{
|
|
const rep = try foundation.String.createWithBytes("hello", .utf8, false);
|
|
defer rep.release();
|
|
str.replaceString(foundation.Range.init(0, 0), rep);
|
|
}
|
|
|
|
str.setAttribute(foundation.Range.init(0, 0), text.FontAttribute.url, null);
|
|
str.setAttribute(foundation.Range.init(0, 0), text.FontAttribute.name.key(), null);
|
|
}
|